Hi,

I built a LM741 based non-inverting amplifier circuit exactly as it is shown in textbooks (figure below). I was expecting it to amplify a 1 Volt (peak) sine wave to about a 5 Volt (peak) sine wave. Instead the output is a steady 11 Volts DC (saturation). I am surprised.


I simulated this circuit using NgSpice. The netlist is listed below along with the LM741 library file. The simulation works correctly. I would be grateful for a hints on what may be going wrong here or a link to any article.

thank you

.lib lib/amp.lib opamp
X741 1 2 3 4 5 LM741
RF   5 2 10k
R1   2 0 2.2k
vin  1 0 sin(0 1v 1kHz)
Vcc  3 0 dc 12V
Vee  4 0 dc -12V
.control
tran 0.01ms 4ms
plot  v(5), v(1)
.endc
.end

.lib OPAMP
*=========
*LM741 Operational Amplifier Macro-Model
*---------------------------------------
*
* connections:     
*                   non-inverting input
*                   |   inverting input
*                   |   |   positive power supply
*                   |   |   |   negative power supply
*                   |   |   |   |   output
*                   |   |   |   |   |
*                   |   |   |   |   |
.SUBCKT LM741       1   2  99  50  28
*
* Features:
* Improved performance over industry standards
* Plug-in replacement for LM709,LM201,MC1439,748
* Input and output overload protection
*
* INPUT STAGE
*
IOS 2 1 20N
* Input offset current
R1 1 3 250K
R2 3 2 250K
I1 4 50 100U
R3 5 99 517
R4 6 99 517
Q1 5 2 4 QX
Q2 6 7 4 QX
*Fp2=2.55 MHz
C4 5 6 60.3614P
*
* COMMON MODE EFFECT
*
I2 99 50 1.6MA
* Quiescent supply current
EOS 7 1 POLY(1) 16 49 1E-3 1
*Input offset voltage.^
R8 99 49 40K
R9 49 50 40K
*
* OUTPUT VOLTAGE LIMITING
V2 99 8 1.63
D1 9 8 DX
D2 10 9 DX
V3 10 50 1.63
*
* SECOND STAGE
*
EH 99 98 99 49 1
G1 98 9 5 6 2.1E-3
*Fp1=5 Hz
R5 98 9 95.493MEG
C3 98 9 333.33P
*
* POLE STAGE
*
*Fp=30 MHz
G3 98 15 9 49 1E-6
R12 98 15 1MEG
C5 98 15 5.3052E-15
*
* COMMON-MODE ZERO STAGE
*
*Fpcm=300 Hz
G4 98 16 3 49 3.1623E-8
L2 98 17 530.5M
R13 17 16 1K
*
* OUTPUT STAGE
*
F6 50 99 POLY(1) V6 450U 1
E1 99 23 99 15 1
R16 24 23 25
D5 26 24 DX
V6 26 22 0.65V
R17 23 25 25
D6 25 27 DX
V7 22 27 0.65V
V5 22 21 0.18V
D4 21 15 DX
V4 20 22 0.18V
D3 15 20 DX
L3 22 28 100P
RL3 22 28 100K
*
***************MODELS USED**************
*
.MODEL DX D(IS=1E-15)
.MODEL QX NPN(BF=625)
*
.ENDS
.endl OPAMP

 

I was expecting it to amplify a 1 Volt (peak) sine wave to about a 5 Volt (peak) sine wave. Instead the output is a steady 11 Volts DC (saturation). I am surprised.

Sine wave from what source?
Might need an input capacitor.
Are the pin numbers configured as below?

 

Offhand can't see any problem with your netlist.

My LTspice sim below looks normal:

 

You're giving us a lot of detail about your simulation, but you say that the simulation is behaving as expected.

On the other hand, you indicate that the problem is with the physical implementation, but provide almost no information about that.

Please show a complete schematic of your physical circuit plus a picture of it -- the problem may be nothing more than a wire connected to the wrong place.

 

Yes, a wiring error is likely in the real circuit.
Double check all the connections.

 

It is also possible that the signal generator source has an adjustable DC offset that is pushing the amp into saturation.
With not enough information about the input, how to guess the output??

 

Remove any DC offset from the signal generator by AC coupling the signal to the amplifier. You will still need to apply a 0 V bias to the input of the amplifier.

 

Because you don't show any bias resistor to 0V on the positive input pin, try a 1k8 resistor from there to 0V, and capacitor couple your input signal to the pin, as MrChips suggests.
The 1k8 resistor equals the parallel combination of the 10k Rf and the 2k2 R1!

 

What was never mentioned was the other connection of the signal generator. If it was to the -12 volts terminal of the supply then of course I would predict about 11volts out.
What we should have been given is the measured voltage on each of the opamp terminals, with the dual supply common as the reference.
Without all of the information we only see guesses based on assumptions.

 

Thank you very much for your replies. They did help me narrow down the problem and identify it. There were no capacitors on input, output and in the feedback bias voltage divider. And I was also splitting a unipolar power supply using a resistor divider to power the OpAm. Fixing all these issues resolved the problem.

Indeed. My simple NgSpice simulation was not capturing the real circuit that I had built.

Thank you again. I very grateful for the range of comments that go me thinking in the right direction.

 

With an op amp powered by a single supply voltage, you don’t split the supply to power the op amp.

You split the supply voltage to create a signal reference voltage equal to Vcc/2.

 

With an op amp powered by a single supply voltage, you don’t split the supply to power the op amp.

You split the supply voltage to create a signal reference voltage equal to Vcc/2.

And if you made all ground connections to that “virtual ground” reference, the circuit would work as long as it does not require significant output current.

 

We call it a “virtual ground”. But note that it is not at 0 V.
I prefer to call it a “common reference”.