This sim works with other op amps I have tried (only 2 or 3 others), but TL072 gets it all wrong, at least using the model that I have.
Has anyone else seen this?

 

Grounding the output of the op amp is an abnormal condition and the model for the TL072 apparently gets it wrong.

 

It's not just you.

It seems that it happens with TI's models of the TL072 and LF353 (they're identical)
Probably the same thing will happen with TI's TL082 model.

The TL07x model on the left is ST Microelectronics' model.

The direct link to their model is here:
http://www.st.com/internet/com/SOFTWARE_RESOURCES/HW_MODEL/SPICE_MODEL/tl07x.txt

I modified it so that I could call it up in different packages if I were going to make a layout in LTSpice for someone:

* saved from url=
* http://www.st.com/stonline/products/families/amplifiers_comparators/macromdl/macromdl/tl07x.txt 
*
* WARNING : please consider following remarks before usage
*
* 1) All models are a tradeoff between accuracy and complexity (ie. simulation time).
*
* 2) Macromodels are not a substitute to breadboarding, they rather confirm the
*    validity of a design approach and help to select surrounding component values.
*
* 3) A macromodel emulates the NOMINAL performance of a TYPICAL device within 
*    SPECIFIED OPERATING CONDITIONS (ie. temperature, supply voltage, etc.).
*    Thus the macromodel is often not as exhaustive as the datasheet, its goal
*    is to illustrate the main parameters of the product.
*
* 4) Data issued from macromodels used outside of its specified conditions
*    (Vcc, Temperature, etc) or even worse: outside of the device operating 
*    conditions (Vcc, Vicm, etc) are not reliable in any way.
.SUBCKT TL071 1 2 3 4 5
XA  1  2  3 4 5 TL07x
.ENDS
.SUBCKT TL072 1 2 3 4 5 6 7 8
XA  1  2  3 4 5 TL07x
XB  6  7  8 4 5 TL07x
.ENDS
.SUBCKT TL074 1 2 3 4 5 6 7 8 9 10 11 12 13 14
XA  1  2  3 4 5 TL07x
XB  6  7  8 4 5 TL07x
XC  9 10 11 4 5 TL07x
XD 12 13 14 4 5 TL07x
.ENDS

** Standard Linear Ics Macromodels, 1993. 
** CONNECTIONS :
*             1 INVERTING INPUT
*             | 2 NON-INVERTING INPUT
*             | | 3 OUTPUT
*             | | | 4 POSITIVE POWER SUPPLY
*             | | | | 5 NEGATIVE POWER SUPPLY
.SUBCKT TL07x 1 2 3 4 5
**********************************************************
.MODEL MDTH D IS=1E-8 KF=5.306587E-14 CJO=10F
* INPUT STAGE
CIP   2  5 1.000000E-12
CIN   1  5 1.000000E-12
EIP  10  5 2 5 1
EIN  16  5 1 5 1
RIP  10 11 1.130435E+00
RIN  15 16 1.130435E+00
RIS  11 15 2.476554E-01
DIP  11 12 MDTH 400E-12
DIN  15 14 MDTH 400E-12
VOFP 12 13 DC 0
VOFN 13 14 DC 0
IPOL 13  5 2.300000E-04
CPS  11 15 4.091333E-08
DINN 17 13 MDTH 400E-12
VIN  17  5 3.000000e+00
DINR 15 18 MDTH 400E-12
VIP   4 18 0.000000E+00
FCP   4  5 VOFP 6.096957E+00
FCN   5  4 VOFN 6.096957E+00
* AMPLIFYING STAGE
FIP   5 19 VOFP 8.217391E+02
FIN   5 19 VOFN 8.217391E+02
RG1  19  5 1.112645E+06
RG2  19  4 1.112645E+06
CC   19 29 1.300000E-08
HZTP 30 29 VOFP 7.743183E+02
HZTN  5 30 VOFN 7.743183E+02
DOPM 19 22 MDTH 400E-12
DONM 21 19 MDTH 400E-12
HOPM 22 28 VOUT 3.750000E+03
VIPM 28  4 1.500000E+02
HONM 21 27 VOUT 3.750000E+03
VINM  5 27 1.500000E+02
EOUT 26 23 19 5 1
VOUT 23  5 0
ROUT 26  3 9.384786E+01
COUT  3  5 1.000000E-12
DOP  19 25 MDTH 400E-12
VOP   4 25 3.259753E+00
DON  24 19 MDTH 400E-12
VON  24  5 3.259753E+00
.ENDS; TL07x

 

Tried the same experiment with National Semiconductor's model of the LF351, which is a single channel version of the LF353, which is about the same as a TL082....
V(x1) is a repeat of the ST Microelectronics' TL07x model
V(x2) is the LF351/NS model
V(g1): 5.08349e-012
V(g2): -0.00499998
V(cc1): 4.5
V(cc2): 4.495
V(ee1): -4.5
V(ee2): -4.505

That's acceptable...

 

This is all in simulations, right?

You would probably be better to use a different symbol than ground.

 

I just examined the models; TI's models use ground internally.

Here's TI's TL072 model; I've placed a *** note under each internal ground reference:

* TL072 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* CREATED USING PARTS RELEASE 4.01 ON 06/16/89 AT 13:08
* (REV N/A)      SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:   NON-INVERTING INPUT
*                | INVERTING INPUT
*                | | POSITIVE POWER SUPPLY
*                | | | NEGATIVE POWER SUPPLY
*                | | | | OUTPUT
*                | | | | |
.SUBCKT TL072/301/TI 1 2 3 4 5
*
  C1   11 12 3.498E-12
  C2    6  7 15.00E-12
  DC    5 53 DX
  DE   54  5 DX
  DLP  90 91 DX
  DLN  92 90 DX
  DP    4  3 DX
  EGND 99  0 POLY(2) (3,0) (4,0) 0 .5 .5
***    *** ^--<< INTERNAL GROUND REFERENCE
  FB    7 99 POLY(5) VB VC VE VLP VLN 0 4.715E6 -5E6 5E6 5E6 -5E6
  GA    6  0 11 12 282.8E-6
***    *** ^--<< INTERNAL GROUND REFERENCE
  GCM   0  6 10 99 8.942E-9
*** *** ^--<< INTERNAL GROUND REFERENCE
  ISS   3 10 DC 195.0E-6
  HLIM 90  0 VLIM 1K
***    *** ^--<< INTERNAL GROUND REFERENCE
  J1   11  2 10 JX
  J2   12  1 10 JX
  R2    6  9 100.0E3
  RD1   4 11 3.536E3
  RD2   4 12 3.536E3
  RO1   8  5 150
  RO2   7 99 150
  RP    3  4 2.143E3
  RSS  10 99 1.026E6
  VB    9  0 DC 0
***    *** ^--<< INTERNAL GROUND REFERENCE
  VC    3 53 DC 2.200
  VE   54  4 DC 2.200
  VLIM  7  8 DC 0
  VLP  91  0 DC 25
***    *** ^--<< INTERNAL GROUND REFERENCE
  VLN   0 92 DC 25
*** *** ^--<< INTERNAL GROUND REFERENCE
.MODEL DX D(IS=800.0E-18)
.MODEL JX PJF(IS=15.00E-12 BETA=270.1E-6 VTO=-1)
.ENDS

I wish they wouldn't do that; there is no reason to do so, and it really goofs up some simulations.

After all, there IS a ground/Vee terminal - they should simply reference that.

I've had similar problems with models like for the LM317, and the LM555. After correcting the internal ground references, they worked fine.

 

I just examined the models; TI's models use ground internally.

Here's TI's TL072 model; I've placed a *** note under each internal ground reference:

* TL072 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* CREATED USING PARTS RELEASE 4.01 ON 06/16/89 AT 13:08
* (REV N/A)      SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:   NON-INVERTING INPUT
*                | INVERTING INPUT
*                | | POSITIVE POWER SUPPLY
*                | | | NEGATIVE POWER SUPPLY
*                | | | | OUTPUT
*                | | | | |
.SUBCKT TL072/301/TI 1 2 3 4 5
*
  C1   11 12 3.498E-12
  C2    6  7 15.00E-12
  DC    5 53 DX
  DE   54  5 DX
  DLP  90 91 DX
  DLN  92 90 DX
  DP    4  3 DX
  EGND 99  0 POLY(2) (3,0) (4,0) 0 .5 .5
***    *** ^--<< INTERNAL GROUND REFERENCE
  FB    7 99 POLY(5) VB VC VE VLP VLN 0 4.715E6 -5E6 5E6 5E6 -5E6
  GA    6  0 11 12 282.8E-6
***    *** ^--<< INTERNAL GROUND REFERENCE
  GCM   0  6 10 99 8.942E-9
*** *** ^--<< INTERNAL GROUND REFERENCE
  ISS   3 10 DC 195.0E-6
  HLIM 90  0 VLIM 1K
***    *** ^--<< INTERNAL GROUND REFERENCE
  J1   11  2 10 JX
  J2   12  1 10 JX
  R2    6  9 100.0E3
  RD1   4 11 3.536E3
  RD2   4 12 3.536E3
  RO1   8  5 150
  RO2   7 99 150
  RP    3  4 2.143E3
  RSS  10 99 1.026E6
  VB    9  0 DC 0
***    *** ^--<< INTERNAL GROUND REFERENCE
  VC    3 53 DC 2.200
  VE   54  4 DC 2.200
  VLIM  7  8 DC 0
  VLP  91  0 DC 25
***    *** ^--<< INTERNAL GROUND REFERENCE
  VLN   0 92 DC 25
*** *** ^--<< INTERNAL GROUND REFERENCE
.MODEL DX D(IS=800.0E-18)
.MODEL JX PJF(IS=15.00E-12 BETA=270.1E-6 VTO=-1)
.ENDS

I wish they wouldn't do that; there is no reason to do so, and it really goofs up some simulations.

After all, there IS a ground/Vee terminal - they should simply reference that.

I've had similar problems with models like for the LM317, and the LM555. After correcting the internal ground references, they worked fine.

I suspected it was due to using ground in the subckt, but I never got around to checking it...

 

This is all in simulations, right?

You would probably be better to use a different symbol than ground.

In an ideal world, you should be able to use any node as ground. TI has moved us into a non-ideal world.

 

Well, thanks for that anyway, Ron - I'd noticed that simulations run using TI's model of the TL07x/TL08x/LF35x ran slower than ST's model, but I'd never really dug into them before.

As a matter of fact I just threw them in my \sub directory a few weeks ago, and hooked them up with a couple of opamp symbols so that I could select them from the SpiceModel pull-down menu. I just hadn't played around with them very much yet.

I'm glad you gave me the heads-up on it; so thanks.

 

Well, thanks for that anyway, Ron - I'd noticed that simulations run using TI's model of the TL07x/TL08x/LF35x ran slower than ST's model, but I'd never really dug into them before.

As a matter of fact I just threw them in my \sub directory a few weeks ago, and hooked them up with a couple of opamp symbols so that I could select them from the SpiceModel pull-down menu. I just hadn't played around with them very much yet.

I'm glad you gave me the heads-up on it; so thanks.

Sometimes our actions have unintended consequences - positive, in this case.
You're welcome.