I found a PSpice model for the SG1525A, but I'm not sure how to use it in LTSpice. I want to model a simple push-pull converter using a SG2525 or similar chip. Any help in finding a model is much appreciated...

 

Look here
http://www.diyaudio.com/forums/power-supplies/165262-sg3525-spice-model-needed.html

 

Here is just the 3525 portion from the MyLib.lib:

* Save as: SG3525A.SUB   in: \Program Files\LTC\SwitcherCad\lib\sub\
*  
.subckt sg3525a INV NI SYN OSC CT RT DCH SS CMP SHD OUA GND VC OUB VIN VRF
A1 N017 0 N009 0 0 N017 N020 0 DFLOP Vhigh=5.1 Trise=20n Rout=30
A2 N018 N019 N009 0 N020 N005 N011 0 OR Vhigh=5.1 Trise=400n Rout=30
A3 N017 N009 0 N019 N018 N023 N022 0 OR Vhigh=5.1 Trise=400n Rout=30
S1 OUA N004 N005 0 HOUT
S2 N012 OUA N011 0 LOUT
S3 OUB N021 N023 0 HOUT
S4 N028 OUB N022 0 LOUT
I1 N031 0 21m
D1 0 N031 IDEAL
R1 N029 N031 8.93
R2 N029 0 22.6
D2 N029 N032 D1_75
D3 0 N032 IDEAL
I2 N032 0 188m
R3 N032 0 2.28
D4 N028 N029 IDEAL
I3 N014 0 21m
D5 0 N014 IDEAL
R4 N013 N014 8.93
R5 N013 0 22.6
D6 N013 N015 D1_75
D7 0 N015 IDEAL
I4 N015 0 188m
R6 N015 0 2.28
D8 N012 N013 IDEAL
D9 VC N021 IDEAL
D10 VC N004 IDEAL
G1 0 N024 NI N027 table=(-70m -100u,0 0,70m 100u)
R7 N024 0 4meg
C1 N024 0 100p
R8 N024 CMP 30
R9 INV 0 1meg
R10 NI 0 1meg
I7 0 VRF 80m
R11 VRF 0 170
D11 0 VRF Z5_1
D12 0 VC Z40
A4 VIN 0 0 0 0 N001 0 0 SCHMITT Vhigh=5.1 Vlow=0.45 Trise=20n Vt=7.25 Vh=0.25
I8 VIN 0 TBL(0 0 3 3.8m 7 19m 8 20m 40 24.1m)
D13 N030 N024 Z5_6
V1 N030 0 0.2
R12 N036 0 5k
R13 SHD N002 5k
Q1 SS N002 N036 0 NPN
D14 N002 0 D1_2
R14 N001 N002 60k
D15 0 SS Z5_1
I9 0 SS 50µ
A5 N002 0 0 0 0 0 N019 0 SCHMITT Vhigh=5.1 Trise=400n Vt=634m Vh=1m
A6 N026 N009 0 0 0 0 N018 0 SRFLOP Vhigh=5.1 Trise=20n Rout=30
A7 0 N025 N019 0 0 0 N026 0 OR Vhigh=5.1 Trise=20n Rout=30
A8 CT N034 0 0 0 0 N025 0 SCHMITT Vhigh=5.1 Trise=20n Vt=0 Vh=10m
E1 N033 0 N024 0 1
E2 N035 0 SS 0 1
R15 N033 N034 500
D16 N034 N035 IDEAL
R16 INV N027 1k
C2 NI N027 40p
R17 SYN 0 2k
R18 OSC N016 250
V2 N003 0 3.64
F1 0 CT V2 -1
D17 N003 RT IDEAL
R19 N016 0 3k
D18 N009 N016 D1_6
S5 0 DCH N009 0 LSW
D19 0 CT Z5_1
A9 N008 N010 0 0 0 0 N009 0 SRFLOP Vhigh=5.1 Ref=0.9 Trise=150n Tfall=250n
A10 N006 N007 0 0 0 0 N008 0 OR Vhigh=5.1 Trise=20n
A11 CT 0 0 0 0 0 N006 0 BUF Vhigh=5.1 Ref=3.2 Trise=20n
A12 CT 0 0 0 0 N010 0 0 BUF Vhigh=5.1 Ref=0.9 Trise=20n
A13 SYN 0 0 0 0 0 N007 0 BUF Vhigh=5.1 Ref=2 Trise=20n
.model NPN NPN
.model PNP PNP
.model HOUT SW(Ron=2.7 Roff=175k Vt=2.8 Vh=-2.1 Vser=1.1 Ilimit=0.6)
.model LOUT SW(Ron=10m Roff=175k Vt=2.8 Vh=-2.1 Vser=0 Ilimit=0.6)
.model IDEAL D(Ron=0 Roff=1G Vfwd=0)
.model D1_75 D(Ron=1.57 Roff=1G Vfwd=1.75)
.model D1_6 D(Ron=0 Roff=1G Vfwd=1.6)
.model Z5_1 D(Ron=1 Roff=1G Vrev=5.075)
.model Z40 D(Ron=0 Roff=175k Vrev=40)
.model Z5_6 D(Ron=1 Roff=1G Vrev=5.6)
.model D1_2 D(Ron=0 Roff=1G Vfwd=1.2)
.model LSW SW(Vt=2.55 Vh=-0.5 Ron=50 Roff=1meg Vser=0.3 Ilimit=50ma)
.ends sg3525a

Here is the symbol for it; save it as:
SG3525A.asy in: \Program Files\LTC\SwitcherCad\lib\sym\

Version 4
SymbolType CELL
RECTANGLE Normal 128 256 -128 -256
WINDOW 3 0 128 Center 0
WINDOW 0 0 -192 Center 0
SYMATTR Prefix X
SYMATTR SpiceModel SG3525A.SUB
SYMATTR Value SG3525A
SYMATTR Value2 sg3525a
SYMATTR Description Push-Pull PWM Controller
PIN -128 96 LEFT 8
PINATTR PinName INV
PINATTR SpiceOrder 1
PIN -128 160 LEFT 8
PINATTR PinName NI
PINATTR SpiceOrder 2
PIN -128 -224 LEFT 8
PINATTR PinName SYN
PINATTR SpiceOrder 3
PIN 128 32 RIGHT 8
PINATTR PinName OSC
PINATTR SpiceOrder 4
PIN -128 -96 LEFT 8
PINATTR PinName CT
PINATTR SpiceOrder 5
PIN -128 -160 LEFT 8
PINATTR PinName RT
PINATTR SpiceOrder 6
PIN -128 -32 LEFT 8
PINATTR PinName DCH
PINATTR SpiceOrder 7
PIN 128 160 RIGHT 8
PINATTR PinName SS
PINATTR SpiceOrder 8
PIN -128 32 LEFT 8
PINATTR PinName CMP
PINATTR SpiceOrder 9
PIN -128 224 LEFT 8
PINATTR PinName SHD
PINATTR SpiceOrder 10
PIN 128 -96 RIGHT 8
PINATTR PinName OUA
PINATTR SpiceOrder 11
PIN 0 256 BOTTOM 8
PINATTR PinName GND
PINATTR SpiceOrder 12
PIN 128 -160 RIGHT 8
PINATTR PinName VC
PINATTR SpiceOrder 13
PIN 128 -32 RIGHT 8
PINATTR PinName OUB
PINATTR SpiceOrder 14
PIN 0 -256 TOP 8
PINATTR PinName VIN
PINATTR SpiceOrder 15
PIN 128 96 RIGHT 8
PINATTR PinName VRF
PINATTR SpiceOrder 16

 

Thanks, very helpful.

 

Good day, I want to simulate this model using Spice as well. Normally I am accustomed to Multisim but I have to use spice for this simulation and I am a newbie at it. Your assistance would be greatly appreciated.

Correct me if I am wrong, SgtWookie I must copy the code, paste it in a text file and save that text file in the folder specified and then do the same with the code for the symbol and save it as SG3525A.asy in the file you stated??

 

You can probably use the .subckt code, but you won't be able to use the symbol text for Multisim; you will have to create your own symbol. It should not be that big of a deal. I don't have Multisim, so you're on your own for that part.

 

Sorry let me explain. I will be using SPICE for the simulation not Multisim. I was just stating that I am normally accustomed to Multisim.
Is the method I stated correct where I save the code as txt files?

There is this file I found in the yahoo group for LT spice but I am not sure how to use it.
http://tech.groups.yahoo.com/group/LTspice/files/ Files sorted by message number/msg_45136/

 

Okay so I used the .subckt code and saved it. I altered the model code you gave up there to the correct pins for the SG1524B and it seems like it worked...now going to test it.

 

Hi, I'm using your code and adding sg3525.sub in lib but doesn't work. Have I run LTspice or compile the library , thank you

 

LTSpice

 

I'm trying use this model but i receive this error. Someone can help me?

 

I'm trying use this model but i receive this error. Someone can help me?


View attachment 192192

Hi

At least post the schematic so we can determine the problem.

Better yet, post all LTspice files....the .asc, .asy and .sub, .lib or .txt library files

eT

 

You can add my model collection to your LTspice from my web page:

http://bordodynov.ltwiki.org/

 

I'm trying use this model but i receive this error. Someone can help me?


View attachment 192192

Hello friend, it is my files. Thanks