Virtual Ground simulation

Discussion in 'General Electronics Chat' started by Ron H, Nov 8, 2011.

  1. Ron H

    Thread Starter AAC Fanatic!

    Apr 14, 2005
    7,050
    657
    This sim works with other op amps I have tried (only 2 or 3 others), but TL072 gets it all wrong, at least using the model that I have.
    Has anyone else seen this?
     
  2. crutschow

    Expert

    Mar 14, 2008
    13,024
    3,236
    Grounding the output of the op amp is an abnormal condition and the model for the TL072 apparently gets it wrong.
     
  3. SgtWookie

    Expert

    Jul 17, 2007
    22,182
    1,728
    It's not just you.

    [​IMG]

    It seems that it happens with TI's models of the TL072 and LF353 (they're identical)
    Probably the same thing will happen with TI's TL082 model.

    The TL07x model on the left is ST Microelectronics' model.

    The direct link to their model is here:
    http://www.st.com/internet/com/SOFTWARE_RESOURCES/HW_MODEL/SPICE_MODEL/tl07x.txt

    I modified it so that I could call it up in different packages if I were going to make a layout in LTSpice for someone:

    Code ( (Unknown Language)):
    1. * saved from url=
    2. * http://www.st.com/stonline/products/families/amplifiers_comparators/macromdl/macromdl/tl07x.txt
    3. *
    4. * WARNING : please consider following remarks before usage
    5. *
    6. * 1) All models are a tradeoff between accuracy and complexity (ie. simulation time).
    7. *
    8. * 2) Macromodels are not a substitute to breadboarding, they rather confirm the
    9. *    validity of a design approach and help to select surrounding component values.
    10. *
    11. * 3) A macromodel emulates the NOMINAL performance of a TYPICAL device within
    12. *    SPECIFIED OPERATING CONDITIONS (ie. temperature, supply voltage, etc.).
    13. *    Thus the macromodel is often not as exhaustive as the datasheet, its goal
    14. *    is to illustrate the main parameters of the product.
    15. *
    16. * 4) Data issued from macromodels used outside of its specified conditions
    17. *    (Vcc, Temperature, etc) or even worse: outside of the device operating
    18. *    conditions (Vcc, Vicm, etc) are not reliable in any way.
    19. .SUBCKT TL071 1 2 3 4 5
    20. XA  1  2  3 4 5 TL07x
    21. .ENDS
    22. .SUBCKT TL072 1 2 3 4 5 6 7 8
    23. XA  1  2  3 4 5 TL07x
    24. XB  6  7  8 4 5 TL07x
    25. .ENDS
    26. .SUBCKT TL074 1 2 3 4 5 6 7 8 9 10 11 12 13 14
    27. XA  1  2  3 4 5 TL07x
    28. XB  6  7  8 4 5 TL07x
    29. XC  9 10 11 4 5 TL07x
    30. XD 12 13 14 4 5 TL07x
    31. .ENDS
    32.  
    33. ** Standard Linear Ics Macromodels, 1993.
    34. ** CONNECTIONS :
    35. *             1 INVERTING INPUT
    36. *             | 2 NON-INVERTING INPUT
    37. *             | | 3 OUTPUT
    38. *             | | | 4 POSITIVE POWER SUPPLY
    39. *             | | | | 5 NEGATIVE POWER SUPPLY
    40. .SUBCKT TL07x 1 2 3 4 5
    41. **********************************************************
    42. .MODEL MDTH D IS=1E-8 KF=5.306587E-14 CJO=10F
    43. * INPUT STAGE
    44. CIP   2  5 1.000000E-12
    45. CIN   1  5 1.000000E-12
    46. EIP  10  5 2 5 1
    47. EIN  16  5 1 5 1
    48. RIP  10 11 1.130435E+00
    49. RIN  15 16 1.130435E+00
    50. RIS  11 15 2.476554E-01
    51. DIP  11 12 MDTH 400E-12
    52. DIN  15 14 MDTH 400E-12
    53. VOFP 12 13 DC 0
    54. VOFN 13 14 DC 0
    55. IPOL 13  5 2.300000E-04
    56. CPS  11 15 4.091333E-08
    57. DINN 17 13 MDTH 400E-12
    58. VIN  17  5 3.000000e+00
    59. DINR 15 18 MDTH 400E-12
    60. VIP   4 18 0.000000E+00
    61. FCP   4  5 VOFP 6.096957E+00
    62. FCN   5  4 VOFN 6.096957E+00
    63. * AMPLIFYING STAGE
    64. FIP   5 19 VOFP 8.217391E+02
    65. FIN   5 19 VOFN 8.217391E+02
    66. RG1  19  5 1.112645E+06
    67. RG2  19  4 1.112645E+06
    68. CC   19 29 1.300000E-08
    69. HZTP 30 29 VOFP 7.743183E+02
    70. HZTN  5 30 VOFN 7.743183E+02
    71. DOPM 19 22 MDTH 400E-12
    72. DONM 21 19 MDTH 400E-12
    73. HOPM 22 28 VOUT 3.750000E+03
    74. VIPM 28  4 1.500000E+02
    75. HONM 21 27 VOUT 3.750000E+03
    76. VINM  5 27 1.500000E+02
    77. EOUT 26 23 19 5 1
    78. VOUT 23  5 0
    79. ROUT 26  3 9.384786E+01
    80. COUT  3  5 1.000000E-12
    81. DOP  19 25 MDTH 400E-12
    82. VOP   4 25 3.259753E+00
    83. DON  24 19 MDTH 400E-12
    84. VON  24  5 3.259753E+00
    85. .ENDS; TL07x
     
    Last edited: Nov 8, 2011
  4. SgtWookie

    Expert

    Jul 17, 2007
    22,182
    1,728
    Tried the same experiment with National Semiconductor's model of the LF351, which is a single channel version of the LF353, which is about the same as a TL082....
    V(x1) is a repeat of the ST Microelectronics' TL07x model
    V(x2) is the LF351/NS model
    V(g1): 5.08349e-012
    V(g2): -0.00499998
    V(cc1): 4.5
    V(cc2): 4.495
    V(ee1): -4.5
    V(ee2): -4.505

    That's acceptable...
     
    Last edited: Nov 8, 2011
  5. Wendy

    Moderator

    Mar 24, 2008
    20,766
    2,536
    This is all in simulations, right?

    You would probably be better to use a different symbol than ground.
     
  6. SgtWookie

    Expert

    Jul 17, 2007
    22,182
    1,728
    I just examined the models; TI's models use ground internally. :rolleyes:

    Here's TI's TL072 model; I've placed a *** note under each internal ground reference:
    Code ( (Unknown Language)):
    1. * TL072 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
    2. * CREATED USING PARTS RELEASE 4.01 ON 06/16/89 AT 13:08
    3. * (REV N/A)      SUPPLY VOLTAGE: +/-15V
    4. * CONNECTIONS:   NON-INVERTING INPUT
    5. *                | INVERTING INPUT
    6. *                | | POSITIVE POWER SUPPLY
    7. *                | | | NEGATIVE POWER SUPPLY
    8. *                | | | | OUTPUT
    9. *                | | | | |
    10. .SUBCKT TL072/301/TI 1 2 3 4 5
    11. *
    12.   C1   11 12 3.498E-12
    13.   C2    6  7 15.00E-12
    14.   DC    5 53 DX
    15.   DE   54  5 DX
    16.   DLP  90 91 DX
    17.   DLN  92 90 DX
    18.   DP    4  3 DX
    19.   EGND 99  0 POLY(2) (3,0) (4,0) 0 .5 .5
    20. ***    *** ^--<< INTERNAL GROUND REFERENCE
    21.   FB    7 99 POLY(5) VB VC VE VLP VLN 0 4.715E6 -5E6 5E6 5E6 -5E6
    22.   GA    6  0 11 12 282.8E-6
    23. ***    *** ^--<< INTERNAL GROUND REFERENCE
    24.   GCM   0  6 10 99 8.942E-9
    25. *** *** ^--<< INTERNAL GROUND REFERENCE
    26.   ISS   3 10 DC 195.0E-6
    27.   HLIM 90  0 VLIM 1K
    28. ***    *** ^--<< INTERNAL GROUND REFERENCE
    29.   J1   11  2 10 JX
    30.   J2   12  1 10 JX
    31.   R2    6  9 100.0E3
    32.   RD1   4 11 3.536E3
    33.   RD2   4 12 3.536E3
    34.   RO1   8  5 150
    35.   RO2   7 99 150
    36.   RP    3  4 2.143E3
    37.   RSS  10 99 1.026E6
    38.   VB    9  0 DC 0
    39. ***    *** ^--<< INTERNAL GROUND REFERENCE
    40.   VC    3 53 DC 2.200
    41.   VE   54  4 DC 2.200
    42.   VLIM  7  8 DC 0
    43.   VLP  91  0 DC 25
    44. ***    *** ^--<< INTERNAL GROUND REFERENCE
    45.   VLN   0 92 DC 25
    46. *** *** ^--<< INTERNAL GROUND REFERENCE
    47. .MODEL DX D(IS=800.0E-18)
    48. .MODEL JX PJF(IS=15.00E-12 BETA=270.1E-6 VTO=-1)
    49. .ENDS
    I wish they wouldn't do that; there is no reason to do so, and it really goofs up some simulations.

    After all, there IS a ground/Vee terminal - they should simply reference that.

    I've had similar problems with models like for the LM317, and the LM555. After correcting the internal ground references, they worked fine.
     
    Last edited: Nov 8, 2011
  7. Ron H

    Thread Starter AAC Fanatic!

    Apr 14, 2005
    7,050
    657
    I suspected it was due to using ground in the subckt, but I never got around to checking it...:(
     
  8. Ron H

    Thread Starter AAC Fanatic!

    Apr 14, 2005
    7,050
    657
    In an ideal world, you should be able to use any node as ground. TI has moved us into a non-ideal world.:rolleyes:
     
  9. SgtWookie

    Expert

    Jul 17, 2007
    22,182
    1,728
    Well, thanks for that anyway, Ron - I'd noticed that simulations run using TI's model of the TL07x/TL08x/LF35x ran slower than ST's model, but I'd never really dug into them before.

    As a matter of fact I just threw them in my \sub directory a few weeks ago, and hooked them up with a couple of opamp symbols so that I could select them from the SpiceModel pull-down menu. I just hadn't played around with them very much yet.

    I'm glad you gave me the heads-up on it; so thanks.
     
  10. Ron H

    Thread Starter AAC Fanatic!

    Apr 14, 2005
    7,050
    657
    Sometimes our actions have unintended consequences - positive, in this case.
    You're welcome.:)
     
Loading...