LTspice model for SG2525/SG3525

Discussion in 'General Electronics Chat' started by tom66, Dec 24, 2011.

  1. tom66

    tom66 Thread Starter Senior Member

    Joined:
    May 9, 2009
    2,613
    212
    I found a PSpice model for the SG1525A, but I'm not sure how to use it in LTSpice. I want to model a simple push-pull converter using a SG2525 or similar chip. Any help in finding a model is much appreciated...
     
    #1
  2. Jony130

    Jony130 Senior Member

    Joined:
    Feb 17, 2009
    3,121
    838
  3. SgtWookie

    SgtWookie Expert

    Joined:
    Jul 17, 2007
    22,160
    1,686
    Here is just the 3525 portion from the MyLib.lib:
    Code ( (Unknown Language)):
    1.  
    2. * Save as: SG3525A.SUB   in: \Program Files\LTC\SwitcherCad\lib\sub\
    3. *  
    4. .subckt sg3525a INV NI SYN OSC CT RT DCH SS CMP SHD OUA GND VC OUB VIN VRF
    5. A1 N017 0 N009 0 0 N017 N020 0 DFLOP Vhigh=5.1 Trise=20n Rout=30
    6. A2 N018 N019 N009 0 N020 N005 N011 0 OR Vhigh=5.1 Trise=400n Rout=30
    7. A3 N017 N009 0 N019 N018 N023 N022 0 OR Vhigh=5.1 Trise=400n Rout=30
    8. S1 OUA N004 N005 0 HOUT
    9. S2 N012 OUA N011 0 LOUT
    10. S3 OUB N021 N023 0 HOUT
    11. S4 N028 OUB N022 0 LOUT
    12. I1 N031 0 21m
    13. D1 0 N031 IDEAL
    14. R1 N029 N031 8.93
    15. R2 N029 0 22.6
    16. D2 N029 N032 D1_75
    17. D3 0 N032 IDEAL
    18. I2 N032 0 188m
    19. R3 N032 0 2.28
    20. D4 N028 N029 IDEAL
    21. I3 N014 0 21m
    22. D5 0 N014 IDEAL
    23. R4 N013 N014 8.93
    24. R5 N013 0 22.6
    25. D6 N013 N015 D1_75
    26. D7 0 N015 IDEAL
    27. I4 N015 0 188m
    28. R6 N015 0 2.28
    29. D8 N012 N013 IDEAL
    30. D9 VC N021 IDEAL
    31. D10 VC N004 IDEAL
    32. G1 0 N024 NI N027 table=(-70m -100u,0 0,70m 100u)
    33. R7 N024 0 4meg
    34. C1 N024 0 100p
    35. R8 N024 CMP 30
    36. R9 INV 0 1meg
    37. R10 NI 0 1meg
    38. I7 0 VRF 80m
    39. R11 VRF 0 170
    40. D11 0 VRF Z5_1
    41. D12 0 VC Z40
    42. A4 VIN 0 0 0 0 N001 0 0 SCHMITT Vhigh=5.1 Vlow=0.45 Trise=20n Vt=7.25 Vh=0.25
    43. I8 VIN 0 TBL(0 0 3 3.8m 7 19m 8 20m 40 24.1m)
    44. D13 N030 N024 Z5_6
    45. V1 N030 0 0.2
    46. R12 N036 0 5k
    47. R13 SHD N002 5k
    48. Q1 SS N002 N036 0 NPN
    49. D14 N002 0 D1_2
    50. R14 N001 N002 60k
    51. D15 0 SS Z5_1
    52. I9 0 SS 50µ
    53. A5 N002 0 0 0 0 0 N019 0 SCHMITT Vhigh=5.1 Trise=400n Vt=634m Vh=1m
    54. A6 N026 N009 0 0 0 0 N018 0 SRFLOP Vhigh=5.1 Trise=20n Rout=30
    55. A7 0 N025 N019 0 0 0 N026 0 OR Vhigh=5.1 Trise=20n Rout=30
    56. A8 CT N034 0 0 0 0 N025 0 SCHMITT Vhigh=5.1 Trise=20n Vt=0 Vh=10m
    57. E1 N033 0 N024 0 1
    58. E2 N035 0 SS 0 1
    59. R15 N033 N034 500
    60. D16 N034 N035 IDEAL
    61. R16 INV N027 1k
    62. C2 NI N027 40p
    63. R17 SYN 0 2k
    64. R18 OSC N016 250
    65. V2 N003 0 3.64
    66. F1 0 CT V2 -1
    67. D17 N003 RT IDEAL
    68. R19 N016 0 3k
    69. D18 N009 N016 D1_6
    70. S5 0 DCH N009 0 LSW
    71. D19 0 CT Z5_1
    72. A9 N008 N010 0 0 0 0 N009 0 SRFLOP Vhigh=5.1 Ref=0.9 Trise=150n Tfall=250n
    73. A10 N006 N007 0 0 0 0 N008 0 OR Vhigh=5.1 Trise=20n
    74. A11 CT 0 0 0 0 0 N006 0 BUF Vhigh=5.1 Ref=3.2 Trise=20n
    75. A12 CT 0 0 0 0 N010 0 0 BUF Vhigh=5.1 Ref=0.9 Trise=20n
    76. A13 SYN 0 0 0 0 0 N007 0 BUF Vhigh=5.1 Ref=2 Trise=20n
    77. .model NPN NPN
    78. .model PNP PNP
    79. .model HOUT SW(Ron=2.7 Roff=175k Vt=2.8 Vh=-2.1 Vser=1.1 Ilimit=0.6)
    80. .model LOUT SW(Ron=10m Roff=175k Vt=2.8 Vh=-2.1 Vser=0 Ilimit=0.6)
    81. .model IDEAL D(Ron=0 Roff=1G Vfwd=0)
    82. .model D1_75 D(Ron=1.57 Roff=1G Vfwd=1.75)
    83. .model D1_6 D(Ron=0 Roff=1G Vfwd=1.6)
    84. .model Z5_1 D(Ron=1 Roff=1G Vrev=5.075)
    85. .model Z40 D(Ron=0 Roff=175k Vrev=40)
    86. .model Z5_6 D(Ron=1 Roff=1G Vrev=5.6)
    87. .model D1_2 D(Ron=0 Roff=1G Vfwd=1.2)
    88. .model LSW SW(Vt=2.55 Vh=-0.5 Ron=50 Roff=1meg Vser=0.3 Ilimit=50ma)
    89. .ends sg3525a
    Here is the symbol for it; save it as:
    SG3525A.asy in: \Program Files\LTC\SwitcherCad\lib\sym\
    Code ( (Unknown Language)):
    1. Version 4
    2. SymbolType CELL
    3. RECTANGLE Normal 128 256 -128 -256
    4. WINDOW 3 0 128 Center 0
    5. WINDOW 0 0 -192 Center 0
    6. SYMATTR Prefix X
    7. SYMATTR SpiceModel SG3525A.SUB
    8. SYMATTR Value SG3525A
    9. SYMATTR Value2 sg3525a
    10. SYMATTR Description Push-Pull PWM Controller
    11. PIN -128 96 LEFT 8
    12. PINATTR PinName INV
    13. PINATTR SpiceOrder 1
    14. PIN -128 160 LEFT 8
    15. PINATTR PinName NI
    16. PINATTR SpiceOrder 2
    17. PIN -128 -224 LEFT 8
    18. PINATTR PinName SYN
    19. PINATTR SpiceOrder 3
    20. PIN 128 32 RIGHT 8
    21. PINATTR PinName OSC
    22. PINATTR SpiceOrder 4
    23. PIN -128 -96 LEFT 8
    24. PINATTR PinName CT
    25. PINATTR SpiceOrder 5
    26. PIN -128 -160 LEFT 8
    27. PINATTR PinName RT
    28. PINATTR SpiceOrder 6
    29. PIN -128 -32 LEFT 8
    30. PINATTR PinName DCH
    31. PINATTR SpiceOrder 7
    32. PIN 128 160 RIGHT 8
    33. PINATTR PinName SS
    34. PINATTR SpiceOrder 8
    35. PIN -128 32 LEFT 8
    36. PINATTR PinName CMP
    37. PINATTR SpiceOrder 9
    38. PIN -128 224 LEFT 8
    39. PINATTR PinName SHD
    40. PINATTR SpiceOrder 10
    41. PIN 128 -96 RIGHT 8
    42. PINATTR PinName OUA
    43. PINATTR SpiceOrder 11
    44. PIN 0 256 BOTTOM 8
    45. PINATTR PinName GND
    46. PINATTR SpiceOrder 12
    47. PIN 128 -160 RIGHT 8
    48. PINATTR PinName VC
    49. PINATTR SpiceOrder 13
    50. PIN 128 -32 RIGHT 8
    51. PINATTR PinName OUB
    52. PINATTR SpiceOrder 14
    53. PIN 0 -256 TOP 8
    54. PINATTR PinName VIN
    55. PINATTR SpiceOrder 15
    56. PIN 128 96 RIGHT 8
    57. PINATTR PinName VRF
    58. PINATTR SpiceOrder 16
     
    Last edited: Dec 24, 2011
    #3
    observativetiger and killivolt like this.
  4. tom66

    tom66 Thread Starter Senior Member

    Joined:
    May 9, 2009
    2,613
    212
    Thanks, very helpful.
     
    #4
  5. Narrin

    Narrin Member

    Joined:
    Oct 2, 2011
    47
    0
    Good day, I want to simulate this model using Spice as well. Normally I am accustomed to Multisim but I have to use spice for this simulation and I am a newbie at it. Your assistance would be greatly appreciated.

    Correct me if I am wrong, SgtWookie I must copy the code, paste it in a text file and save that text file in the folder specified and then do the same with the code for the symbol and save it as SG3525A.asy in the file you stated??
     
    Last edited: Nov 5, 2012
    #5
  6. SgtWookie

    SgtWookie Expert

    Joined:
    Jul 17, 2007
    22,160
    1,686
    You can probably use the .subckt code, but you won't be able to use the symbol text for Multisim; you will have to create your own symbol. It should not be that big of a deal. I don't have Multisim, so you're on your own for that part.
     
    #6
  7. Narrin

    Narrin Member

    Joined:
    Oct 2, 2011
    47
    0
    Last edited: Nov 5, 2012
    #7
  8. Narrin

    Narrin Member

    Joined:
    Oct 2, 2011
    47
    0
    Okay so I used the .subckt code and saved it. I altered the model code you gave up there to the correct pins for the SG1524B and it seems like it worked...now going to test it.
     
    #8
Loading...