Has anyone made a component in Multisim using the component wizard? I want to simulate the LM25011 buck regulator so I downloaded the PSPICE files from the Texas Instruments website but none of the files have similar data to an example I used to create the THS7001 shown below.
The zip folder has .lib, .OLB, .DSN and .opj files but looking at the data with notepad it doesnt look like the .cir file data I used for the THS7001. Anyone know what to do?
Code:
THERM_PREAMP.CIR - THERMISTOR WITH PREAMP GAIN AND OFFSET
*
* TEMPERATURE
VTEMP 20 0 PWL(0MS 0DEG 100MS 40DEG)
RD1 10 0 1MEG
*
* SENSOR BRIDGE
VBIAS 12 0 DC 5V
XTH1 12 1 20 0 NTC_10K
RBIAS 1 0 10K
RA 12 2 10K
RB 2 0 10K
*
* 3 OPAMP INSTRUMENTATION AMPLIFIER
* GAIN STAGE
XOP1 2 4 6 OPAMP1
R1 4 6 10K
R2 4 5 17.883K
R3 5 7 10K
XOP2 1 5 7 OPAMP1
* DIFF AMP
R4 6 8 10K
R5 8 10 10K
R6 7 9 10K
R7 9 11 10K
XOP3 9 8 10 OPAMP1
VOFF 11 0 DC 2.569V
*
* MEASUREMENT ERROR
E_ERR 21 0 VALUE = { V(10)*10-V(20)}
RD2 21 0 1MEG
* THERMISTOR SUBCIRCUIT ****************************************
* thermistor terminals : 1,2
* temperature (deg C) input+,-: 4,5
*
.SUBCKT NTC_10K 1 2 4 5
ETHERM 1 3 VALUE = {i(VSENSE)*10K*EXP( 3450/(V(4,5)+273.15)-3450/(25+273.15))}
VSENSE 3 2 DC 0
.ENDS
*
* OPAMP MACRO MODEL, SINGLE-POLE *******************************
* connections: non-inverting input
* | inverting input
* | | output
* | | |
.SUBCKT OPAMP1 1 2 6
* INPUT IMPEDANCE
RIN 1 2 10MEG
* GAIN BANDWIDTH PRODUCT = 10MHZ
* DC GAIN (100K) AND POLE 1 (100HZ)
EGAIN 3 0 1 2 100K
RP1 3 4 1K
CP1 4 0 1.5915UF
* OUTPUT BUFFER AND RESISTANCE
EBUFFER 5 0 4 0 1
ROUT 5 6 10
.ENDS
*
*
* ANALYSIS
.TRAN 1MS 100MS
*
* VIEW RESULTS
.PRINT TRAN V(1) V(10)
.PROBE
.END